; JB demo music, probably made for Maniacs of Noise
	; Converted from TurboAssembler to ACME by dmx87

	!to "Bjerregaard_J_James_Bond_3.sid",plain

	* = $0000
	
	!text "PSID"
	!be16 2							; version 2
	!be16 $7c						; data offset
	!be16 $1000							; Load (0 = auto)
	!be16 SETMUS						; Init
	!be16 PLAY						; Play
	!be16 2							; num songs
	!be16 1							; first song
	!word 0
	!word 0
-	!text "James Bond 3 Demo"
	!fill 32 - (* - -)
-	!text "Johannes Bjerregaard"
	!fill 32 - (* - -)
-	!text "1989 Johannes Bjerregaard"
	!fill 32 - (* - -)
	!be16 $0014							; v2 flags
	!be16 0							; Start page, page length (reloc)
	!be16 0							; Reserved

!pseudopc $1000 {



;---------------------------------------
ZP       = $FC;(ZP+1 ALSO USED)
;---------------------------------------
INITMUS  = 0

         ;IMPROVEMENTS:
         ;------------

         ;"2ND SUSTAIN"
         ;SET1+7 BIT 4-7 = LEVEL

         ;RELEASE ONLY WHILE RESTING

         ;(!)CHIP RESET ALWAYS

         ;AUTO SUSTAIN DELAY
         ;SET1+6 BIT 5-7 = TIME=FRAMES

         ;RELEASE TRIGGER
         ;SET1+3 BIT 4-7 = 2*TIME=FRAMES

         ;DON'T FORGET:
         ;FILTER SEQUENCE END/STOP
         ;RECOGNITION BYTES CHANGED!
;---------------------------------------
         ;RECEIVED        : 18/6

         ;LATEST DELIVERY : 19/6

         ;ROOM            : ...

         ;ZERO PAGE       : ...

         ;SPECIFICATIONS  : 30 SECS OF
         ;                  JAMES BOND
         ;                  TITLE TUNE
         ;                  INCLUDING
         ;                  A DEMO OF
         ;                  THE MANIACS
         ;                  OF NOISE
         ;                  MUSIC STYLE
;---------------------------------------
        ; *= $0801
        ; !by $21,$08,$C5,$07,$9E,$32
        ; !by $30,$38,$33,$20,$53,$A4
        ; !by $52,$4D,$20,$4C,$B0,$44
        ; !by $20,$4D,$55,$53,$49,$43
        ; !by $20,$28,$43,$29,$4D,$91
        ; !by $2E,$00,$00,$00

;         JMP DEMO
         JMP SETMUS;INIT(.A=MUSIC NO)
         JMP MUSOFF;STOPS PLAYING TUNE
         JMP PLAY;JSR IN IRQ-INTERRUPT

FADERATE !by 0;STORE FADE RATE(1-127)
                ;HERE.....

PLAY

MUSON    = *+1
         LDA #0
         BNE PLAYIT
         RTS

PLAYIT   LDX #2

         DEC TEMPOCNT
NEXTV
         LDA TEMPOCNT
         BPL DOPE

TEMPOSET = *+1

         LDA #2
         STA TEMPOCNT
         DEC LEN
         DEC LEN+1
         DEC LEN+2

DOPE     LDA LEN,X
         BPL DONOT

         LDA TEMPOCNT
         CMP #1
         BEQ READVALS
         BCS DONOT
         JMP SETVALS

DONOT    JMP COMPUTE
;---------------------------------------
READVALS
         TXA
         ASL
         TAY

         LDA MUSSTART,Y
         STA ZP
         LDA MUSSTART+1,Y
         STA ZP+1

         LDY SEQNO,X

REREAD   LDA (ZP),Y;READ SEQUENCE NO.

         BPL LESS

         CMP #$FF
         BNE NOTREP

         LDY #0
         STY SEQNO
         STY SEQNO+1
         STY SEQNO+2
         LDA #$00
         STY NEWRELOFF
         STY NEWRELOFF+1
         STY NEWRELOFF+2
         JMP REREAD

NOTREP   CMP #$FE
         BNE NOTEND
;---------------------------------------
MUSOFF   LDA #0
         STA MUSON
         STA $D404
         STA $D404+7
         STA $D404+14
         RTS
;---------------------------------------
NOTEND   AND #$7F
         SEC
         SBC #$40
         STA TRANSP,X
         INY
         INC SEQNO,X
         JMP REREAD
;---------------------------------------
LESS     TAY         ;READ SEQUENCE DATA
         LDA LOSEQ,Y
         STA ZP
         LDA HISEQ,Y
         STA ZP+1

         LDA GATE,X
         AND #$FE
         STA GATE,X

         LDY SEQPTR,X

REREAD2  LDA (ZP),Y

         CMP #$60
         BCS DYTT
         JMP NOTT

DYTT     CMP #$80;$60-$7F=ARPEGGIO
         BCS NOTARP2

         AND #$1F
         STA ARPSELECT,X

         INY
         JMP REREAD2

NOTARP2  CMP #$FC;TIE NEXT TWO NOTES
         BNE NOTARP

         DEC NOPCOUNTER,X

         LDA #$FE
         STA GATE,X
         INY
         JMP REREAD2

NOTARP   CMP #$E0
         BCC NOTPAUSE

         AND #$1F
         STA LEN,X
         INY
         TYA
         STA SEQPTR,X

         LDA LAST,X
         BNE DONTSET

         LDY ENVPTR,X
         LDA SET1+7,Y
         AND #$F0
         ORA RELEASE,X
         STA RELEASE,X

         LDY D4POINT,X

         LDA WFM,X
         AND #$FE
         STA $D404,Y
         LDA #0
         STA $D405,Y

         LDA RELEASE,X
         STA $D406,Y

         LDA #$FE
         STA GATE,X

         DEC WFPCOUNTER,X

         LDA #0
         STA NEWRELOFF,X

         LDA #1
         STA LAST,X
DONTSET
         LDY SEQPTR,X

         LDA (ZP),Y
         CMP #$FF
         BNE JCMP2

         INC SEQNO,X
         LDA #0
         STA SEQPTR,X
JCMP2
         JMP SETSID

NOTPAUSE CMP #$C0
         BCC NOTLEN

         AND #$1F
         STA SETLEN,X
         STA NLEN,X
         INY
         JMP REREAD2
NOTLEN
         PHA
         LDA SETLEN,X
         STA NLEN,X
         PLA

         CMP #$A0
         BCC NOTGLIDE

         AND #$1F
         STA GLIDE,X
         INY
         LDA (ZP),Y
         CLC
         ADC TRANSP,X
         STA ENDNOTE,X
         INY
         JMP REREAD2

NOTGLIDE ;THIS GOTTA BE $80-$9F

         AND #$1F
         ASL
         ASL
         ASL
         STA ENVPTR,X
         STY TEMP

         TAY
         LDA SET1+4,Y
         AND #$1F
         STA ARPSELECT,X

         LDY TEMP
         INY
         JMP REREAD2

READ2    INY
         LDA (ZP),Y

NOTT     CLC
         ADC TRANSP,X
         STA NOTE,X

         INY
         TYA
         STA SEQPTR,X

         LDA (ZP),Y
         CMP #$FF
         BNE WHI2

         LDA #0
         STA SEQPTR,X
         INC SEQNO,X
WHI2
         LDA GATE,X
         AND #1
         BNE WHI

         LDY D4POINT,X
         LDA #$F0
         STA $D404,Y
         STA WFM,X
WHI
         JMP AZ

;------------------------------------
SETVALS
         LDY ENVPTR,X
         STY TEMP2

         LDA SET1+2,Y
         AND #$0F
         LSR
         STA VIBDIR,X;VIBRATO DIRECTION

         LDA SET1+1,Y
         AND #$0F
         STA RELEASE,X

         LDA NLEN,X
         STA LEN,X

         LDA #0
         STA VIBRATE,X
         STA VIBRATEHI,X
         STA LAST,X

         LDA GATE,X
         AND #$01
         BEQ BURP

         JMP COMPUTE

BURP     STX TEMP
         STA RELCTR,X

         STA PWTIMES,X
         STA FTMS,X

         LDA #$80
         STA NEWRELOFF,X

         LDA D4POINT,X
         LDY TEMP2

         TAX
         LDA #0
         STA $D404,X

         LDA SET1,Y
         STA $D405,X
         LDA SET1+1,Y
         STA $D406,X

         LDX TEMP

         LDA #9;BYTE 0 = REPEAT POINT
         STA WFM,X

         LDA #1
         STA VIBCOUNTER,X;VIB(DELAY)
         STA WFPCOUNTER,X;WAVEFORM
         STA NOPCOUNTER,X;ARPEGGIO

         LDA #2;BYTE 1=TRIG VALUE
         STA PWPCOUNTER,X;PULSE WIDTH

         LDA #3
         STA FIPCOUNTER,X;SET+D418

         LDY TEMP2

         LDA #$FF
         STA GATE,X

         LDA SET1+3,Y
         AND #$0F
         TAY

         LDA PUTABLO,Y
         STA FIX
         LDA PUTABHI,Y
         STA FIX+1

         LDY #1
FIX      = *+1
         LDA $1234,Y
         STA LOPW,X
         AND #$0F
         STA HIPW,X

         LDY ENVPTR,X
         LDA SET1+5,Y
         AND #$0F
         TAY

         LDA FITABLO,Y
         STA ZP
         LDA FITABHI,Y
         STA ZP+1

         LDY #1
         LDA (ZP),Y
         BEQ FILTOFF

         STA CTOF

         INY
         LDA (ZP),Y
         STA D418

         LDA D417
         ORA FONT,X
         STA D417
         JMP GUF

FILTOFF  LDA D417
         AND FOFFT,X
         STA D417

GUF      JMP SETSID
;---------------------------------------
COMPUTE
         ;WAVEFORMS

         LDY ENVPTR,X
         LDA SET1+6,Y
         AND #$0F
         TAY

         LDA WFTABLO,Y
         STA ZP
         LDA WFTABHI,Y
         STA ZP+1

         LDY WFPCOUNTER,X

RE       LDA (ZP),Y
         CMP #$FE
         BCC WAVEFORM

         BEQ NOCHANG;LAST WF REACHED

         LDY #0
         LDA (ZP),Y
         TAY
         JMP RE

WAVEFORM STA WFM,X
         INY
         TYA
         STA WFPCOUNTER,X
;---------------------------------------
NOCHANG

         ;ARPEGGIO (SET NOTES)

         LDY ARPSELECT,X

         LDA NOTABLO,Y
         STA ZP
         LDA NOTABHI,Y
         STA ZP+1

         LDY #0
         LDA (ZP),Y
         STA TMP1

         LDY NOPCOUNTER,X

RE2      LDA (ZP),Y
         CMP #$FE
         BCC NOTEOK

         BEQ VIBRATO

         LDY #0
         LDA (ZP),Y
         AND #$7F
         TAY
         JMP RE2
NOTEOK
         BIT TMP1
         BPL NOTESET

         STA HIFQ,X
         LDA #0
         STA LOFQ,X
         INY
         TYA
         JMP WACK
NOTESET
         CMP #$80
         AND #$7F
         BCS STEADY

         CLC
         ADC NOTE,X

STEADY   INY
         STY TEMP

         STA TEMPNOTE,X
         TAY

         LDA FQDATLO,Y
         STA LOFQ,X
         LDA FQDATHI,Y
         STA HIFQ,X

         LDA TEMP
WACK
         STA NOPCOUNTER,X

         JMP NOVIBR
;---------------------------------------
VIBRATO
         LDA GLIDE,X
         BNE NOTVIB

         LDY ENVPTR,X
         LDA SET1+2,Y
         AND #$F0;DELAY
         LSR
         LSR
         LSR

         CMP VIBCOUNTER,X
         BCC VIBR
NOTVIB   JMP NOVIBR
VIBR
         LDY TEMPNOTE,X

         LDA FQDATLO,Y
         SEC
         SBC FQDATLO-1,Y
         LDA FQDATHI,Y
         SBC FQDATHI-1,Y
         CLC
         ADC #1
         STA ZP

         LDY ENVPTR,X
         LDA SET1+7,Y
         AND #$0F
         TAY ;VIBRATO RATE

         LDA ZP

ROLLOVER DEY
         BMI ENOUGH

         ASL
         JMP ROLLOVER

ENOUGH   STA ZP
         LDY ENVPTR,X

         LDA SET1+2,Y
         AND #$0F
         LSR
         CMP VIBDIR,X
         BCS VIBDOWN

         LDA LOFQ,X
         CLC
         ADC VIBRATE,X
         STA LOFQ,X
         LDA HIFQ,X
         ADC VIBRATEHI,X
         STA HIFQ,X
         JMP SETRATE

VIBDOWN  LDA LOFQ,X
         SEC
         SBC VIBRATE,X
         STA LOFQ,X
         LDA HIFQ,X
         SBC VIBRATEHI,X
         STA HIFQ,X

SETRATE  LDA SET1+5,Y
         AND #$F0
         LSR
         LSR
         CMP VIBCOUNTER,X
         BCC DIRINC
         LDA ZP
         CLC
         ADC VIBRATE,X
         STA VIBRATE,X
         LDA VIBRATEHI,X
         ADC #0
         STA VIBRATEHI,X

DIRINC   INC VIBDIR,X
         LDA SET1+2,Y
         AND #$0F
         CMP VIBDIR,X
         BCS NOVIBR
         LDA #0
         STA VIBDIR,X
;---------------------------------------
NOVIBR   ;PULSE WIDTH PROGRAMMING

         LDY ENVPTR,X
         LDA SET1+3,Y
         AND #$0F
         TAY

         LDA PUTABLO,Y
         STA ZP
         LDA PUTABHI,Y
         STA ZP+1

         LDY PWPCOUNTER,X

         LDA PWTIMES,X
         BNE STORESAME

REREAD4  LDA (ZP),Y

         CMP #$FE
         BCC VALUEOK

         BEQ NOMOREPW

         LDY #0
         LDA (ZP),Y
         TAY
         JMP REREAD4
STORESAME
         LDA PWVALUE,X

VALUEOK  STA PWVALUE,X

         CMP #$80
         AND #$7F
         BCS ADD

         ASL
         STA TEMP
         LDA LOPW,X
         SEC
         SBC TEMP
         STA LOPW,X

         LDA HIPW,X
         SBC #0
         STA HIPW,X

GETTIMES LDA PWTIMES,X
         BNE DECPWT

         INY
         LDA (ZP),Y
         STA PWTIMES,X

         INY
         TYA
         STA PWPCOUNTER,X

         JMP NOMOREPW

ADD      ASL
         CLC
         ADC LOPW,X
         STA LOPW,X

         LDA HIPW,X
         ADC #0
         STA HIPW,X

         JMP GETTIMES

DECPWT   DEC PWTIMES,X
;---------------------------------------
NOMOREPW ;FILTER PROGRAMMING

         LDY ENVPTR,X
         LDA SET1+5,Y
         AND #$07
         TAY

         LDA FITABLO,Y
         STA ZP
         LDA FITABHI,Y
         STA ZP+1

         LDY FIPCOUNTER,X

         LDA FTMS,X
         BNE READSAME

RRREAD   LDA (ZP),Y
         CMP #$7E
         BEQ NOFILTCHANGE

         CMP #$7F
         BNE ADDSUBOK

         LDY #0
         LDA (ZP),Y
         STA FIPCOUNTER,X
         TAY
         JMP RRREAD

READSAME LDA FDTA,X
ADDSUBOK STA FDTA,X

         LDA CTOF
         CLC
         ADC FDTA,X
         STA CTOF

         LDA FTMS,X
         BNE NOTIMESET

         INY
         LDA (ZP),Y
         STA FTMS,X

         INY
         TYA
         STA FIPCOUNTER,X

NOTIMESET DEC FTMS,X
;---------------------------------------
NOFILTCHANGE

         ;GLIDE

         LDA GLIDE,X
         BNE GLOK
         JMP ZD

GLOK     LDY ENDNOTE,X
         LDA FQDATLO,Y
         STA ZP
         LDA FQDATHI,Y
         STA ZP+1

         LDA #0
         STA TEMP2

         LDA #$0F
         LDY GLIDE,X

LOOPING  DEY
         BMI NOMOREOFTHAT

         ASL
         ROL TEMP2

         JMP LOOPING

NOMOREOFTHAT
         STA TEMP

         LDA ENDNOTE,X
         CMP TEMPNOTE,X
         BCS GLIDEUP

         LDA LOFQ,X
         SEC
         SBC TEMP
         STA LOFQ,X
         LDA HIFQ,X
         SBC TEMP2
         STA HIFQ,X

         LDA LOFQ,X
         SEC
         SBC ZP
         LDA HIFQ,X
         SBC ZP+1
         BCS ZD

GLIDEND  LDA #0
         STA GLIDE,X

         LDA ZP
         STA LOFQ,X

         LDA ZP+1
         STA HIFQ,X
         JMP ZD
GLIDEUP
         LDA LOFQ,X
         CLC
         ADC TEMP
         STA LOFQ,X

         LDA HIFQ,X
         ADC TEMP2
         STA HIFQ,X

         LDA ZP
         SEC
         SBC LOFQ,X
         LDA ZP+1
         SBC HIFQ,X
         BCS ZD
         JMP GLIDEND
;---------------------------------------
ZD
Z3       INC VIBCOUNTER,X

         LDY ENVPTR,X
         LDA SET1+6,Y
         AND #%11100000
         BEQ NOWAYPAL
         LSR
         LSR
         LSR
         LSR
         LSR
         CMP RELCTR,X
         BNE NOWAYPAL

         LDA SET1+7,Y
         AND #$F0
         ORA RELEASE,X
         STA RELEASE,X

         LDY D4POINT,X

         LDA WFM,X
         AND #$FE
         STA $D404,Y
         LDA #0
         STA $D405,Y

         LDA RELEASE,X
         STA $D406,Y

         LDA #0
         STA NEWRELOFF,X

NOWAYPAL
         INC RELCTR,X


;---------------------------------------
SETSID
         LDA NEWRELOFF,X
         BMI WEG2
         LDY ENVPTR,X
         LDA SET1+3,Y
         AND #$F0
         LSR
         LSR
         LSR
         CMP NEWRELOFF,X
         BCS WEG

         LDA #$FE
         STA GATE,X
WEG
         INC NEWRELOFF,X
WEG2
         LDY D4POINT,X

         LDA WFM,X
         AND GATE,X
         STA $D404,Y

         LDA LOFQ,X
         STA $D400,Y

         LDA HIFQ,X
         STA $D401,Y

         LDA LOPW,X
         STA $D402,Y

         LDA HIPW,X
         STA $D403,Y
AZ
         LDA LEN,X
         BPL Z2
         LDA TEMPOCNT
         CMP #$02
         BNE Z2
         LDY D4POINT,X
         LDA #$00
         STA $D406,Y
         STA $D405,Y

Z2       DEX
         BMI SETVOL
         JMP NEXTV
SETVOL
         LDA D417
         STA $D417

         LDA CTOF
         STA $D416

         LDA FADERATE
         BEQ STOREIT

         DEC FADECOUNTER
         BPL STOREIT

         LDA VOLUME
         BEQ STOREIT

         LDA FADERATE
         STA FADECOUNTER

         DEC VOLUME

STOREIT  LDA D418
         ORA VOLUME
         STA $D418
         LDA VOLUME
         BNE OUTAHERE
         JMP MUSOFF

OUTAHERE RTS
;---------------------------------------
TEMPOCNT !by 0
SETLEN   !by 0,0,0
TRANSP   !by 0,0,0
NONEW    !by 0,0,0
SEQNO    !by 0,0,0
SEQPTR   !by 0,0,0
GLIDE    !by 0,0,0
NLEN     !by 0,0,0
D4POINT  !by 0,7,14
TEMP     !by 0
TEMP2    !by 0
ENDNOTE  !by 0,0,0
ENVPTR   !by 0,0,0
VIBCOUNTER !by 0,0,0
FIPCOUNTER !by 0,0,0
WFPCOUNTER !by 0,0,0
NOPCOUNTER !by 0,0,0
PWPCOUNTER !by 0,0,0
VIBDIR   !by 0,0,0
WFM      !by 0,0,0
GATE     !by 0,0,0
LEN      !by 0,0,0
LOFQ     !by 0,0,0
HIFQ     !by 0,0,0
TEMPNOTE !by 0,0,0
VIBRATE  !by 0,0,0
VIBRATEHI !by 0,0,0
NOTE     !by 0,0,0
LOPW     !by 0,0,0
HIPW     !by 0,0,0
PWTIMES  !by 0,0,0
PWVALUE  !by 0,0,0
FTMS     !by 0,0,0
FDTA     !by 0,0,0
CTOF     !by 0
D418     !by 0
D417     !by 0
TEMPD417 !by 0
ARPSELECT !by 0,0,0
MUSSTART !by 0,0,0,0,0,0
FONT     !by $F1,$F2,$F4
FOFFT    !by $FE,$FD,$FB
FADECOUNTER !by 0
VOLUME   !by 0
RELEASE  !by 0,0,0
NEWRELOFF !by 0,0,0
LAST     !by 0,0,0
RELCTR   !by 0,0,0
TMP1     !by 0
;---------------------------------------
SETMUS
         ASL
         ASL
         ASL
         TAX

         LDA START+1,X
         STA TEMPOSET

         LDY #0
         STY FADERATE

LOOP     LDA START+2,X
         STA MUSSTART,Y
         INX
         LDA #0
         STA GATE,Y
         STA TRANSP,Y
         STA SEQNO,Y
         STA GLIDE,Y
         LDA #1
         STA NEWRELOFF,Y
         INY
         CPY #6
         BNE LOOP

         LDA #$0F
         STA $D404
         STA $D404+7
         STA $D404+14
         STA VOLUME

         STY MUSON
         LDA #0
         STA TEMPOCNT
         STA $D406
         STA $D406+7
         STA $D406+14

         RTS
;---------------------------------------
START    !by 2,4;TITLE THEME
         !wo V0,V1,V2

         !by 2,4;IN-GAME TUNE
         !wo V3,V4,V5

         !by 2,2
         !wo V6,V7,V8
;---------------------------------------
; DEMO

         ; LDA #0
         ; STA $D020
         ; STA $D021

         ; LDA #<TEXT
         ; LDY #>TEXT
         ; JSR $AB1E

         ; SEI
         ; LDA #1
         ; STA $D01A
         ; STA $DC0D

         ; LDA #$1B
         ; STA $D011

         ; LDA #<INT
         ; STA $0314

         ; LDA #>INT
         ; STA $0315

         ; LDA #INITMUS
         ; JSR SETMUS
         ; CLI
; EDE
         ; JSR $FFE4
         ; BEQ EDE
         ; CMP #"Q"
         ; BNE WG
         ; JMP $9000
; WG
         ; CMP #" "
         ; BNE ED2
         ; LDA #$06
         ; STA FADERATE
         ; JMP EDE
; ED2
         ; CMP #"1"
         ; BCC EDE
         ; CMP #"4"
         ; BCS EDE
         ; AND #$07
         ; SEC
         ; SBC #1
         ; JSR SETMUS
         ; LDA #0
         ; STA TIME
         ; STA TIME+1
         ; STA TIME+2
         ; JMP EDE

; TEXT
         ; .TEXT "“    


; "
         ; .TEXT "ÐLAYER AND MUSIC  BY"
         ; .TEXT " ÊOZZ ÂJERREGAARD..."
         ; .TEXT "                    "
         ; .TEXT "                    "
         ; !by 13

         ; .TEXT "›ÐRESS:              "
         ; .TEXT "                    "
         ; .TEXT "1 JAMES BOND DEMO   "
         ; .TEXT "                    "
         ; .TEXT "                    "
         ; .TEXT "                    "
         ; .TEXT "ÓPACE TO FADE AWAY  "
         ; .TEXT "_ FOR FAST FORWINDIN"
         ; !by 0
---------------------------------------
; INT
         ; LDA #58
         ; STA $D012
         ; LSR $D019

         ; LDA #6
         ; STA $D020
         ; JSR PLAY
         ; JSR TIM
         ; LDX #0
         ; STX $D020

         ; LDA $DC01
         ; AND #2
         ; BNE ROTTEN
; CHK
         ; LDA $DC01
         ; AND #2
         ; BNE ROT
         ; JSR PLAY
         ; JSR TIM
         ; JMP CHK
; ROT
; ROTTEN
         ; JMP $EA31
---------------------------------------
; TIM
         ; SED
         ; LDA TIME
         ; CLC
         ; ADC #1
         ; STA TIME
         ; CMP #$50
         ; BNE DAV1
         ; LDA #0
         ; STA TIME
         ; LDA TIME+1
         ; CLC
         ; ADC #1
         ; STA TIME+1
         ; CMP #$60
         ; BNE DAV1
         ; LDA #0
         ; STA TIME+1
         ; LDA TIME+2
         ; CLC
         ; ADC #1
         ; STA TIME+2
; DAV1
         ; LDA TIME+1
         ; AND #$0F
         ; CLC
         ; ADC #$30
         ; STA $0403
         ; LDA TIME+1
         ; LSR A
         ; LSR A
         ; LSR A
         ; LSR A
         ; CLC
         ; ADC #$30
         ; STA $0402
         ; LDA #":"
         ; AND #$3F
         ; STA $0401
         ; LDA TIME+2
         ; AND #$0F
         ; CLC
         ; ADC #$30
         ; STA $0400
         ; CLD
         ; RTS

; TIME     !by 0,0,0
;---------------------------------------
LOSEQ
         !by <S00,<S01,<S02,<S03
         !by <S04,<S05,<S06,<S07
         !by <S08,<S09,<S0A,<S0B
         !by <S0C,<S0D,<S0E,<S0F
         !by <S10,<S11,<S12,<S13
         !by <S14,<S15,<S16,<S17
         !by <S18,<S19,<S1A,<S1B
         !by <S1C,<S1D,<S1E,<S1F
         !by <S20,<S21,<S22,<S23
         !by <S24,<S25,<S26,<S27
         !by <S28,<S29,<S2A,<S2B
         !by <S2C,<S2D,<S2E,<S2F
         !by <S30,<S31,<S32,<S33
         !by <S34,<S35,<S36,<S37
         !by <S38,<S39,<S3A,<S3B
         !by <S3C
HISEQ
         !by >S00,>S01,>S02,>S03
         !by >S04,>S05,>S06,>S07
         !by >S08,>S09,>S0A,>S0B
         !by >S0C,>S0D,>S0E,>S0F
         !by >S10,>S11,>S12,>S13
         !by >S14,>S15,>S16,>S17
         !by >S18,>S19,>S1A,>S1B
         !by >S1C,>S1D,>S1E,>S1F
         !by >S20,>S21,>S22,>S23
         !by >S24,>S25,>S26,>S27
         !by >S28,>S29,>S2A,>S2B
         !by >S2C,>S2D,>S2E,>S2F
         !by >S30,>S31,>S32,>S33
         !by >S34,>S35,>S36,>S37
         !by >S38,>S39,>S3A,>S3B
         !by >S3C

WFTABLO  !by <W0,<W1,<W2,<W3
         !by <W4,<W5,<W6,<W7
         !by <W8,<W9,<WA,<WB
         !by <WC
WFTABHI  !by >W0,>W1,>W2,>W3
         !by >W4,>W5,>W6,>W7
         !by >W8,>W9,>WA,>WB
         !by >WC

NOTABLO  !by <N0,<N1,<N2,<N3
         !by <N4,<N5,<N6,<N7
         !by <N8,<N9,<NA,<NB
         !by <NC,<ND,<NE,<NF
         !by <N10,<N11,<N12
NOTABHI  !by >N0,>N1,>N2,>N3
         !by >N4,>N5,>N6,>N7
         !by >N8,>N9,>NA,>NB
         !by >NC,>ND,>NE,>NF
         !by >N10,>N11,>N12

PUTABLO  !by <P0,<P1,<P2,<P3
         !by <P4,<P5,<P6,<P7
         !by <P8,<P9
PUTABHI  !by >P0,>P1,>P2,>P3
         !by >P4,>P5,>P6,>P7
         !by >P8,>P9

FITABLO  !by <F0,<F1,<F2,<F3
         !by <F4
FITABHI  !by >F0,>F1,>F2,>F3
         !by >F4
FQDATLO
         !by $17,$27,$39,$4C,$5F,$74
         !by $8A,$A2,$BB,$D5,$F1,$0F
         !by $2E,$4F,$72,$98,$BF,$E9
         !by $15,$44,$76,$AB,$E3,$1E
         !by $5C,$9F,$E5,$30,$7F,$D2
         !by $2B,$89,$ED,$56,$C6,$3C
         !by $B9,$3E,$CB,$60,$FE,$A5
         !by $57,$13,$DA,$AC,$8C,$79
         !by $73,$7D,$96,$C1,$FD,$4B
         !by $AE,$26,$B4,$59,$18,$F2
         !by $E7,$FA,$2D,$82,$FA,$97
         !by $5C,$4C,$68,$B3,$31,$E4
         !by $CF,$F5,$5B,$04,$F4,$2F
         !by $B9,$98,$D0,$67,$62,$C8
         !by $9E,$EB,$B7,$09,$E8,$5E
         !by $73,$31,$A1,$CF,$C5,$FF
FQDATHI
         !by $01,$01,$01,$01,$01,$01
         !by $01,$01,$01,$01,$01,$02
         !by $02,$02,$02,$02,$02,$02
         !by $03,$03,$03,$03,$03,$04
         !by $04,$04,$04,$05,$05,$05
         !by $06,$06,$06,$07,$07,$08
         !by $08,$09,$09,$0A,$0A,$0B
         !by $0C,$0D,$0D,$0E,$0F,$10
         !by $11,$12,$13,$14,$15,$17
         !by $18,$1A,$1B,$1D,$1F,$20
         !by $22,$24,$27,$29,$2B,$2E
         !by $31,$34,$37,$3A,$3E,$41
         !by $45,$49,$4E,$53,$57,$5D
         !by $62,$68,$6E,$75,$7C,$83
         !by $8B,$93,$9C,$A6,$AF,$BA
         !by $C5,$D1,$DD,$EA,$F8,$FF
;---------------------------------------
          ;*** THE JAMES BOND DEMO ***
;---------------------------------------
      ;NOTHING
S00      !by $EF,$EF,$EF,$EF,$FF

S01
         !by $80,$C7,$2F
         !by $30,$31,$30,$2F,$30
         !by $31,$30,$FF
S02
         !by $80,$C7,$2B,$2B,$2B
         !by $2B,$2B,$2B,$2B,$2B,$FF
S03
         !by $81,$C3,$1C
         !by $82,$1C
         !by $81,$1C
         !by $82,$1C
         !by $81,$1C
         !by $82,$1C
         !by $81,$1C
         !by $82,$1C

         !by $81,$1C
         !by $82,$1C
         !by $81,$1C
         !by $82,$1C
         !by $81,$1C
         !by $82,$1C
         !by $81,$1C
         !by $82,$1C
         !by $FF
S04
         !by $83,$C1
         !by $1C,$C0,$1E,$1E,$C1,$1E
         !by $C3,$1E,$C1,$1C,$1C,$1C
         !by $1C,$C0,$1F,$1F,$C1,$1F
         !by $C3,$1F,$C1,$1E,$1E,$1E
         !by $83,$C1
         !by $1C,$C0,$1E,$1E,$C1,$1E
         !by $C3,$1E,$C1,$1C,$1C,$1C
         !by $1C,$C0,$1F,$1F,$C1,$1F
         !by $C3,$1F,$C1,$1E,$1C,$1E
         !by $83,$C1
         !by $1C,$C0,$1E,$1E,$C1,$1E
         !by $C3,$1E,$C1,$1C,$1C,$1C
         !by $1C,$C0,$1F,$1F,$C1,$1F
         !by $C3,$1F,$C1,$1E,$1D,$1C
         !by $27,$C9,$26,$C1,$23,$21
         !by $CF,$23,$FF

S05
         !by $80,$C7,$66
         !by $2B,$67,$2B,$68,$2B
         !by $67,$2B
         !by $80,$C7,$66
         !by $2B,$67,$2B,$68,$2B
         !by $67,$2B
         !by $80,$C7,$69
         !by $2B,$6A,$2B,$6B,$2B
         !by $6A,$2B
         !by $80,$C7,$69
         !by $2B,$6A,$2B,$6B,$2B
         !by $6A,$2B
         !by $FF
S06
         !by $84,$C2,$33
         !by $C2,$33,$E5
         !by $C2,$33
         !by $C2,$33,$E5

         !by $C0,$33,$C1,$33,$C0,$33
         !by $C1,$33,$C2,$33,$EB
         !by $C3,$85,$2D,$FF

S07
         !by $85,$C2,$2D
         !by $C2,$2D,$E5
         !by $85,$C2,$2D
         !by $C2,$2D,$E5

         !by $C0,$2D,$C1,$2D,$C0,$2D
         !by $C1,$2D,$C2,$2D,$EF,$FF
S08
         !by $E2,$E2,$E0,$C6
         !by $C4,$82,$0B
         !by $E2,$E2,$E0,$C6
         !by $C4,$82,$0B
         !by $E0,$E1,$E0,$E1,$E3
         !by $C8,$82,$0B,$C1
         !by $1A,$1C,$10,$FF
S09
         !by $C1,$82,$13,$81,$15
         !by $17,$C3,$82,$18,$C1,$17
         !by $81,$15,$10
         !by $82,$11,$81,$11,$15
         !by $82,$C3,$10,$C1,$81,$10
         !by $14,$10
         !by $C1,$82,$13,$81,$15
         !by $17,$C3,$82,$18,$C1,$17
         !by $81,$15,$10
         !by $82,$11,$81,$15,$18
         !by $82,$C3,$1C,$C1,$81,$17
         !by $14,$10,$FF
S0A
         !by $87,$C1,$6D,$34,$C1,$34
         !by $86,$2D
         !by $87,$C3,$6D,$34,$C1,$34
         !by $86,$2D,$87,$70,$30
         !by $87,$C1,$71,$30,$30
         !by $86,$2D
         !by $87,$C3,$6F,$34,$C1,$34
         !by $86,$2D
         !by $87,$70,$34
         !by $87,$C1,$6D,$34,$C1,$34
         !by $86,$2D
         !by $87,$C3,$6D,$34,$C1,$34
         !by $86,$2D,$87,$70,$30
         !by $87,$C1,$71,$30,$70,$35
         !by $86,$2D
         !by $87,$C3,$6F,$39,$C1
         !by $72,$38
         !by $86,$2D
         !by $87,$70,$34,$FF

S0B
         !by $E1
         !by $C1,$88,$34,$39,$3B
         !by $3C,$E1,$3E,$E1,$C2
         !by $A2,$3C,$3B
         !by $3B,$C1,$39,$C3,$3B
         !by $C2,$32,$D0,$34
         !by $E1
         !by $C1,$89,$45,$43,$41
         !by $40,$3C,$43,$C3,$40
         !by $88,$C1,$34,$39,$3B
         !by $3C,$E1,$3E,$E1,$C2,$40
         !by $41,$C1,$40,$C3,$3B
         !by $C2,$A2,$3C,$3B,$D0,$39
         !by $E1
         !by $C1,$89,$48,$47,$43
         !by $3E,$40,$C0,$3C,$3B
         !by $C1,$39,$FF

S0C
S0D
S0E
S0F
S10
S11
S12
S13
S14
S15
S16
S17
S18
S19
S1A
S1B
S1C
S1D
S1E
S1F
S20
S21
S22
S23
S24
S25
S26
S27
S28
S29
S2A
S2B
S2C
S2D
S2E
S2F
S30
S31
S32
S33
S34
S35
S36
S37
S38
S39
S3A
S3B
S3C
;---------------------------------------
         ;TITLE
V0
         !by $C0,$01,$CC,$04,$C0,$06
         !by $09,$09,$09,$09,$FF
V1
         !by $C0,$02,$05,$07
         !by $0A,$0A,$0A,$0A,$FF
V2
         !by $C0,$03,$03,$03,$08
         !by $0B,$0B,$FF
;---------------------------------------
V3
         !by $CC,$09,$09,$09,$09,$FF
V5
         !by $C0,$0A,$0A,$0A,$0A,$FF
V4
         !by $C0,$0B,$FF
;---------------------------------------
V6
V7
V8
;---------------------------------------
SET1
         ;0=ATK/DCY
         ;1=SUS1/REL
         ;2=VIB1
         ;3=PULSE/DLY
         ;4=NOTES
         ;5=FILTER
         ;6=WAVES
         ;7=VIB2/SUS2

;INTROSINGLECHORD
         !by $00,$30,$19,$01
         !by $04,$10,$03,$12;0

;INTROFILTERBASS1
         !by $0A,$A7,$00,$01
         !by $04,$01,$03,$10;1

;INTROFILTERBASS+DRUM
         !by $0A,$A7,$17,$01
         !by $05,$22,$04,$31;2

;GUITAR
         !by $08,$6C,$79,$02
         !by $04,$80,$05,$01;3

;ORCH HIT ......HMMM
         !by $06,$59,$10,$03
         !by $0C,$00,$06,$10;4
;DRUMM
         !by $06,$A9,$00,$00
         !by $03,$00,$01,$00;5
;DRUM
         !by $06,$A8,$00,$00
         !by $03,$00,$01,$00;6
;SONGCHORDS
         !by $04,$38,$19,$01
         !by $04,$10,$03,$00;7
;MELODY
         !by $06,$50,$17,$04
         !by $04,$20,$07,$51;8
;JEROEN PLOINK
         !by $08,$86,$17,$00
         !by $04,$20,$08,$23;9
;
         !by $03,$99,$27,$A1
         !by $09,$31,$83,$31
;
         !by $06,$47,$00,$04
         !by $00,$00,$08,$00;B
;
         !by $08,$69,$00,$00
         !by $0D,$00,$09,$00;C
;
         !by $07,$87,$13,$00
         !by $07,$F0,$07,$04;D
;
         !by $01,$36,$00,$08
         !by $10,$00,$0A,$00;E
;
         !by $00,$6B,$00,$00
         !by $00,$01,$0B,$00;F
;
         !by $00,$00,$00,$00
         !by $00,$01,$00,$00;10
;
         !by $00,$4A,$00,$09
         !by $00,$01,$06,$00;11
;
         !by $00,$8A,$19,$00
         !by $11,$71,$0C,$02;12
;
         !by $00,$4A,$39,$05
         !by $00,$61,$06,$01;13
;
         !by $03,$69,$97,$09
         !by $0B,$71,$06,$05;14
;
         !by $09,$89,$00,$00
         !by $03,$01,$09,$00;15
;---------------------------------------
         ;WAVEFORM PROGRAM SEQUENCES

W0       ;BASSDRUM
         !by $01,$81,$41,$40,$FE

W1       ;LONGSNARE
         !by $01,$81,$11,$40,$80
         !by $40,$80,$FE

W2       ;SNARE
         !by $01,$81,$41,$40,$80
         !by $FE

W3       ;INTROSINGLCHRD
         !by $01,$21,$21,$41,$FE

W4       ;INTROFILTEREDBASS+BASSDRUM
         !by $01,$81,$41,$FE

W5       ;GUITAR
         !by $01,$43,$43,$43,$40,$FE

W6       ;ORCH HIT
         !by $01,$21,$21,$41,$FE
W7
         !by $01,$21,$21,$41,$FE
W8
         !by $01,$11,$FE
W9
WA
WB
WC
;---------------------------------------
         ;ARP/NOTE PROGRAM SEQUENCES

N0
         !by $01,$04,$04,$00,$FF
N1
         !by $01,$03,$03,$00,$FF
N2
         !by $81
         !by $58,$08,$06,$04
         !by $03,$02,$03,$04,$03,$FE
N3
         !by $86
         !by $3D,$16,$0B,$3D
         !by $0D,$3D,$31,$10
         !by $3D,$10,$FF
N4
         !by $01,$00,$FE
N5
         !by $01,$BF,$A2,$9A,$00
         !by $FE
N6
         !by $01,$04,$00,$00,$04,$FF
N7
         !by $01,$05,$00,$00,$05,$FF
N8
         !by $01,$06,$00,$00,$06,$FF
N9
         !by $01,$10,$00,$00,$04,$FF
NA
         !by $01,$11,$00,$00,$05,$FF
NB
         !by $01,$12,$00,$00,$06,$FF
NC
         !by $01,$0B,$08,$04,$00,$FF
ND
         !by $01,$08,$05,$00,$08,$FF
NE
         !by $01,$07,$03,$00,$07,$FF
NF
         !by $01,$07,$05,$00,$07,$FF
N10
         !by $01,$07,$04,$00,$07,$FF
N11
         !by $01,$09,$04,$00,$09,$FF
N12
         !by $01,$08,$03,$00,$08,$FF
;---------------------------------------
         ;PULSE WIDTH PROGRAM SEQUENCES

         ;BYTE 0 = REPEAT POINT
         ;BYTE 1 = LO/HI PULSE WIDTH

P0       !by $00,$08,$FE

P1
         !by $01,$DC
         !by $20,$04
         !by $10,$04
         !by $08,$04
         !by $04,$04,$FE
P2     ;GUITAR
         !by $01,$E0
         !by $C0,$01
         !by $B0,$01
         !by $A0,$02
         !by $10,$03
         !by $08,$04,$FE
P3    ;ORCH
         !by $02,$FF
         !by $30,$01
         !by $20,$01
         !by $18,$01
         !by $13,$08,$FF
P4
         !by $08,$08
         !by $08,$01
         !by $10,$01
         !by $18,$01
         !by $28,$05
         !by $A8,$05,$FF

P5
P6
P7
P8
P9
;---------------------------------------
         ;FILTER PROGRAM SEQUENCES

         ;BYTE 1=CUTOFF TRIGGER VALUE
         ;BYTE 2=FILTER PASS (0=OFF)

F0       !by $01,$00,$00,$7E

F1
         !by $01,$80,$10
         !by $F0,$06,$7E
F2
         !by $01,$F0,$10
         !by $00,$01
         !by $90,$01
         !by $F0,$06,$7E
F3
F4

}